Релиб / Программирование / Visual Basic / Сортировка в MSFlexGrid / Latest Posts

RE: Сортировка в MSFlexGrid

systopler — Mon, 30 Apr 2007 07:19:38 GMT

Спасибо за функцию :)

У меня тоже все замечательно работает!

RE: Сортировка в MSFlexGrid

VladConn — Fri, 26 May 2006 16:12:57 GMT

Insolent,

U menya vse rabotaet:

Private Sub Command1_Click()
MSHFlexGrid1.Sort = 9 'flexSortCustom
End Sub

Private Sub Form_Load()
With MSHFlexGrid1
.Cols = 2
.AddItem 1 & vbTab & Date
.AddItem 2 & vbTab & Date - 1
.AddItem 3 & vbTab & Date + 1
.AddItem 4 & vbTab & Date - 5
End With
End Sub

Private Sub MSHFlexGrid1_Compare(ByVal Row1 As Long, ByVal Row2 As Long, Cmp As Integer)
CustomSort MSHFlexGrid1, 1, Row1, Row2, Cmp, True
End Sub

Private Sub CustomSort(ByRef pGrid As MSHFlexGrid, _
ByVal pCol As Long, _
ByVal pRow1 As Long, _
ByVal pRow2 As Long, _
ByRef pCmp As Integer, _
ByRef pSortAscending As Boolean)

Dim varRow1 As Variant
Dim varRow2 As Variant

On Error GoTo MethodError

With pGrid

If IsNumeric(.TextMatrix(pRow1, pCol)) And IsNumeric(.TextMatrix(pRow2, pCol)) Then

varRow1 = CDbl(.TextMatrix(pRow1, pCol))
varRow2 = CDbl(.TextMatrix(pRow2, pCol))

ElseIf IsDate(.TextMatrix(pRow1, pCol)) And IsDate(.TextMatrix(pRow2, pCol)) Then

varRow1 = CDate(.TextMatrix(pRow1, pCol))
varRow2 = CDate(.TextMatrix(pRow2, pCol))

Else

varRow1 = CStr(Trim$(.TextMatrix(pRow1, pCol)))
varRow2 = CStr(Trim$(.TextMatrix(pRow2, pCol)))

End If

If varRow1 < varRow2 Then
pCmp = -1
ElseIf varRow1 > varRow2 Then
pCmp = 1
Else
pCmp = 0
End If

If Not pSortAscending Then
pCmp = pCmp * -1
End If

End With

MethodError:
If Err.Number <> 0 Then
MsgBox "Error " & Err.Description & " in CustomSort"
End If

End Sub

RE: Сортировка в MSFlexGrid

Insolent — Wed, 24 May 2006 00:11:21 GMT

пиши собственную процедуру сортировки, основанную на каком-нибудь быстром алгоритме, я делал по способу Шелла:)

Сортировка в MSFlexGrid

ulitsky — Sun, 14 May 2006 11:10:52 GMT

Сортировка MSFlexGrid.Sort по колонке, в которой содержатся данные типа Date или Date+Time происходит неверно. Как решить эту проблему, если данные берутся не из базы, а из массива ?